pvsblur
Prev | Orchestra Opcodes and Operators | Next

## pvsblur

pvsblur — Average the amp/freq time functions of each analysis channel for a specified time.

## Description

Average the amp/freq time functions of each analysis channel for a specified time (truncated to number of frames). As a side-effect the input pvoc stream will be delayed by that amount.

## Syntax

    fsig pvsblur fsigin, kblurtime, imaxdel

## Performance

fsig -- output pv stream

fsigin -- input pv stream.

kblurtime -- time in secs during which windows will be averaged .

imaxdel -- maximum delay time, used for allocating memory used in the averaging operation.

This opcode will blur a pvstream by smoothing the amplitude and frequency time functions (a type of low-pass filtering); the amount of blur will depend on the length of the averaging period, larger blurtimes will result in a more pronounced effect.

| Warning
It is unsafe to use the same f-variable for both input and output of pvs opcodes. Using the same one might lead to undefined behavior on some opcodes. Use a different one on the left and right sides of the opcode.

## Examples

Here is an example of the use of the pvsblur opcode. It uses the file pvsblur.csd.

Example 810. Example of the pvsblur opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

     <CsoundSynthesizer>
     <CsOptions>
     ; Select audio/midi flags here according to platform
     ; Audio out   Audio in
     -odac       ;;;RT audio out
     ; For Non-realtime ouput leave only the line below:
     ; -o pvsblur.wav -W ;;; for file output any platform
     </CsOptions>
     <CsInstruments>

     sr = 44100
     ksmps = 32
     nchnls = 2
     0dbfs  = 1

     ;; example written by joachim heintz 2009

     instr 1
     ifftsize	= 1024
     ioverlap	= ifftsize / 4
     iwinsize	= ifftsize
     iwinshape	= 1               ; von-Hann window
     Sfile	= "fox.wav"
     ain		soundin	Sfile
     fftin	pvsanal	ain, ifftsize, ioverlap, iwinsize, iwinshape; fft-analysis of the audio-signal
     fftblur	pvsblur	fftin, p4, 1; blur
     aout		pvsynth	fftblur; resynthesis
     		outs	aout, aout
     endin

     </CsInstruments>
     <CsScore>
     i 1 0 3    0
     i 1 3 3   .1
     i 1 6 3.5 .5
     e
     </CsScore>
     </CsoundSynthesizer>

## See Also

pvsanal, pvsynth, pvsadsyn

## Credits

Author: Victor Lazzarini
November 2004

New plugin in version 5

November 2004.

Prev | Up | Next
pvsbin | Home | pvsbuffer