Inhoud

# functie OPMAAKPROFIEL

Past een stijl toe op de cel die de formule bevat. Na een bepaalde tijd kan een andere stijl worden toegepast.

Deze functie retourneert altijd de numerieke waarde 0, waardoor deze kan worden gebruikt door de functie OPMAAKPROFIEL toe te voegen aan andere functies in dezelfde cel zonder de waarde te wijzigen.

De functie OPMAAKPROFIEL mag niet zonder dwingende reden worden gebruikt; het doel ervan is het gebruik met asynchrone Add-In-functies om visueel te informeren over de beschikbaarheid van een resultaat. In bijna alle andere gevallen is het gebruik van voorwaardelijke opmaak een betere keuze.

### Syntaxis

OPMAAKPROFIEL(Opmaakprofiel ; Tijd (Optioneel); Opmaakprofiel 2 (optioneel))

Opmaakprofiel is de naam van het celopmaakprofiel dat op de cel moet worden toegepast. Namen van opmaakprofielen zijn niet hoofdlettergevoelig en moeten tussen aanhalingstekens worden geplaatst.

Tijd is een optioneel tijdbereik in seconden. Nadat deze tijd is verstreken, wordt het opmaakprofiel die is gedefinieerd in Opmaakprofiel 2 toegepast. Laat deze parameter leeg als u niet wilt dat het opmaakprofiel wordt gewijzigd.

Opmaakprofiel 2 is de optionele naam van een celopmaakprofiel die aan de cel wordt toegewezen nadat de tijd die is opgegeven in de parameter Tijd is verstreken. Als deze parameter ontbreekt, wordt het celopmaakprofiel "Standaard" toegepast.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

### Voorbeelden

=10+OPMAAKPROFIEL("Goed";60;"Neutraal")

Voert de waarde 10 in de cel in en past het opmaakprofiel met de naam "Goed" toe. Na 60 seconden wordt het opmaakprofiel "Neutraal" toegepast.

=A1*A2+OPMAAKPROFIEL(ALS(HUIDIG()<100;"Slecht";"Goed"))

Voert het resultaat in van het vermenigvuldigen van de waarden in cellen A1 en A2 en past het opmaakprofiel "Slecht" toe als het resultaat kleiner is dan 100, anders wordt het opmaakprofiel "Goed" toegepast. Hier wordt de functie HUIDIG() gebruikt om de momenteel geëvalueerde waarde van de functie in de cel te krijgen.

="Totaal"&T(OPMAAKPROFIEL("Resultaat"))

Voert de tekst "Totaal" in de cel in en past het opmaakprofiel met de naam "Resultaat" toe. Merk op dat dit voorbeeld gaat over tekstuele waarden, daarom moet de uitvoer van de functie OPMAAKPROFIEL aan de tekst worden toegevoegd met behulp van de &-operator. De functie T() wordt gebruikt om te voorkomen dat het cijfer "0" wordt toegevoegd aan de resulterende tekst.

#### Technische informatie

Deze functie maakt geen deel uit van de Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula) indeling standaard. De naamafstand is

ORG.OPENOFFICE.STYLE

Verwante onderwerpen

Wiki-pagina STIJL.

werkbladfuncties

Opmaak toewijzen op basis van formule

functie HUIDIG

functie T