Съдържание
Индекс 🔎︎

# Услуга ScriptForge.Array

Предоставя набор от методи за манипулиране и трансформиране на едномерни масиви (вектори) и двумерни масиви (матрици). Това включва операции с множества, сортиране, импортиране от и експортиране към текстови файлове.

Масиви с повече от две измерения не могат да се използват с методите в тази услуга, с изключение само на метода CountDims, който приема масиви с произволен брой измерения.

Елементите на масивите могат да съдържат стойности от всякакъв тип, включително (под)масиви.

## Извикване на услугата

Преди да използвате услугата Array, библиотеката ScriptForge трябва да бъде заредена чрез:

        GlobalScope.BasicLibraries.loadLibrary("ScriptForge")

Зареждането на библиотеката ще създаде обекта SF_Array, който може да бъде използван за извикване на методите на услугата Array.

Следващите откъси код показват различни начини за извикване на методите в услугата Array (методът Append е използван като пример):

        Dim arr : arr = Array(1, 2, 3)
        arr = SF_Array.Append(arr, 4)

        Dim arr : arr = Array(1, 2, 3)
        Dim svc : svc = SF_Array
        arr = svc.Append(arr, 4)

        Dim arr : arr = Array(1, 2, 3)
        Dim svc : svc = CreateScriptService("Array")
        arr = svc.Append(arr, 4)

Тъй като Python има вградена поддръжка за списъци и кортежи, повечето методи в услугата Array са налични само за скриптове на Basic. Единственото изключение е ImportFromCSVFile, който се поддържа и в Basic, и в Python.

Списък с методи на услугата Array
Append AppendColumn AppendRow Contains ConvertToDictionary Copy CountDims Difference ExportToTextFile ExtractColumn ExtractRow | Flatten ImportFromCSVFile IndexOf Insert InsertSorted Intersection Join2D Prepend PrependColumn PrependRow RangeInit | Reverse Shuffle Slice Sort SortColumns SortRows Transpose TrimArray Union Unique

Първият аргумент на повечето методи е разглежданият обект масив. Той винаги се предава по адрес и остава непроменен. Методите като Append, Prepend и т.н. връщат нов обект масив след изпълнението си.

## Append

Добавя елементите, изброени като аргументи, в края на входния масив.

### Синтаксис:

svc.Append(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

### Параметри:

array_1d: съществуващият масив, може да е празен.

arg0, arg1, ...: елементи, които ще бъдат добавени към array_1d.

### Пример:

        Dim a As Variant
        a = SF_Array.Append(Array(1, 2, 3), 4, 5)
            ' (1, 2, 3, 4, 5)

## AppendColumn

Добавя нова колона към дясната страна на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

### Синтаксис:

svc.AppendColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

### Параметри:

array_2d: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за първа колона на получения двумерен масив.

column: едномерен масив с толкова елементи, колкото са редовете в array_2d.

### Пример:

        Dim a As Variant, b As variant
        a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
            ' ((1, 4), (2, 5), (3, 6))
        b = SF_Array.AppendColumn(a, Array(7, 8, 9))
            ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
        c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i

## AppendRow

Добавя нов ред към долната страна на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

### Синтаксис:

svc.AppendRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])

### Параметри:

array_2d: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за първи ред на получения двумерен масив.

row: едномерен масив с толкова елементи, колкото са колоните в array_2d.

### Пример:

        Dim a As Variant, b As variant
        a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
            '  ((1, 2, 3), (4, 5, 6))
        b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i

## Contains

Проверява дали едномерен масив съдържа определено число, текст или дата. Сравняването на текст може да бъде или да не бъде чувствително към регистъра.
Сортираните входни масиви трябва да бъдат запълнени хомогенно, тоест всички елементи трябва да са скалари от един и същ тип (елементи със стойност Empty и Null са забранени).
Резултатът от метода е непредсказуем, когато масивът е обявен като сортиран, но в действителност не е такъв.
Ако масивът е сортиран, се извършва двоично търсене, в противен случай той просто се обхожда от началото до края и елементите Empty и Null се игнорират.

### Синтаксис:

svc.Contains(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool

### Параметри:

array_1d: масивът за обхождане.

tofind: търсено число, дата или низ.

casesensitive: само за сравняване на низове, подразбира се False.

sortorder: може да бъде "ASC" (възходящо сортиран), "DESC" (низходящо сортиран) или "" (несортиран). Подразбираната стойност е "".

### Пример:

        Dim a As Variant
        a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
        SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False

## ConvertToDictionary

Съхранява съдържанието на масив с две колони в обект от тип ScriptForge.Dictionary.
Ключът се извлича от първата колона, а елементът – от втората.

### Синтаксис:

svc.ConvertToDictionary(array_2d: any[0..*, 0..1]): obj

### Параметри:

array_2d: данни, които да бъдат преобразувани в обект от типа ScriptForge.Dictionary.

- Първата колона трябва да съдържа само низове с ненулева дължина, в произволен ред. Тези стойности ще бъдат използвани като ключове в асоциативния масив.

- Втората колона съдържа данните, които ще бъдат асоциирани със съответните ключове.

### Пример:

        Dim a As Variant, b As Variant
        a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
        b = SF_Array.ConvertToDictionary(a)
        MsgBox b.Item("c") ' 3

## Copy

Създава копие на едномерен или двумерен масив.

### Синтаксис:

svc.Copy(array_nd: any[0..*]): any[0..*]

svc.Copy(array_nd: any[0..*, 0..*]): any[0..*, 0..*]

### Параметри:

array_nd: едномерният или двумерен масив, който да бъде копиран.

### Пример:

Простото присвояване на обект от типа Array копира адреса му, а не създава копие на съдържанието на кобекта. Вижте следния пример:

        Dim a as Variant, b as Variant
        a = Array(1, 2, 3)
        ' Присвояването по-долу е по адрес.
        b = a
        ' Затова променянето на стойности в b ще промени и a.
        b(0) = 10
        MsgBox a(0) ' 10

С използването на метода Copy се създава копие на целия обект Array. В долния пример a и b са различни обекти и прменянето на стойности в b няма да се отрази на стойностите в a.

        Dim a as Variant, b as Variant
        a = Array(1, 2, 3)
        ' Създава копие на a чрез метода Copy.
        b = SF_Array.Copy(a)
        b(0) = 10
        MsgBox a(0) ' 1

## CountDims

Преброява измеренията на масив. Резултатът може да е по-голям от две.
Ако аргументът не е масив, връща -1.
Ако масивът не е инициализиран, връща 0.

### Синтаксис:

svc.CountDims(array_nd: any): int

### Параметри:

array_nd: разглежданият масив.

### Пример:

        Dim a(1 To 10, -3 To 12, 5)
        MsgBox SF_Array.CountDims(a) ' 3

## Difference

Конструира множество във вид на индексиран от нула масив, като прилага операцията разлика върху двата входни масива. Резултатът включва елементите, които присъстват в първия масив, но не и във втория.
Резултатният масив е сортиран във възходящ ред.
Двата входни масива трябва да са попълнени хомогенно, елементите им трябва да са скалари от един и същ тип. Елементи със стойност Empty и Null са забранени.
Сравняването на текст може да бъде чувствително или нечувствително към регистъра.

### Синтаксис:

svc.Difference(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Параметри:

array1_1d: едномерен отправен масив, чиито елементи се преглеждат за премахване.

array2_1d: едномерен масив, чиито елементи се изваждат от първия входен масив.

casesensitive: този аргумент е приложим само ако масивите са попълнени с низове (подразбира се False).

### Пример:

        Dim a As Variant
        a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
            ' ("A", "B")

## ExportToTextFile

Записва всички елементи на масива последователно в текстов файл. Ако файлът вече съществува, той ще бъде заменен без предупреждение.

### Синтаксис:

svc.ExportToTextFile(array_1d: any[0..*], filename: str, [encoding: str]): bool

### Параметри:

array_1d: масивът за експортиране. Той трябва да съдържа само низове.

filename: името на текстовия файл, в който ще се запишат данните. Името трябва да бъде изразено според текущото свойство FileNaming на услугата SF_FileSystem.

encoding: знаковият набор, който трябва да се използва. Използвайте име от списъка със знакови набори на IANA. Имайте предвид, че LibreOffice може да не поддържа всички съществуващи знакови набори (подразбира се "UTF-8").

### Пример:

        SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")

## ExtractColumn

Извлича указана колона от двуизмерен масив като нов масив.
Долната и горната му граница, LBound и UBound, са идентични на тези на първото измерение на входния масив.

### Синтаксис:

svc.ExtractColumn(array_2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]

### Параметри:

array_2d: масивът, от който се извлича.

columnindex: номерът на колоната за извличане – трябва да е в интервала [LBound, UBound].

### Пример:

        'Създава матрица 3x3: |1, 2, 3|
        '                      |4, 5, 6|
        '                      |7, 8, 9|
        Dim mat as Variant, col as Variant
        mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
        mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
        mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
        'Извлича третата колона: |3, 6, 9|
        col = SF_Array.ExtractColumn(mat, 2)

## ExtractRow

Извлича указан ред от двуизмерен масив като нов масив.
Долната и горната му граница, LBound и UBound, са идентични на тези на второто измерение на входния масив.

### Синтаксис:

svc.ExtractRow(array_2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]

### Параметри:

array_2d: масивът, от който се извлича.

rowindex: номерът на реда за извличане – трябва да е в интервала [LBound, UBound].

### Пример:

        'Създава матрица 3x3: |1, 2, 3|
        '                      |4, 5, 6|
        '                      |7, 8, 9|
        Dim mat as Variant, row as Variant
        mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
        mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
        mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
        'Извлича първия ред: |1, 2, 3|
        row = SF_Array.ExtractRow(mat, 0)

## Flatten

Подрежда всички единични елементи на масив и всички елементи на подмасивите му в един нов масив без подмасиви. Празните подмасиви се игнорират, а подмасивите с повече от едно измерение не се изравняват.

### Синтаксис:

svc.Flatten(array_1d: any[0..*]): any[0..*]

### Параметри:

array_1d: съществуващият масив, може да е празен.

### Пример:

        Dim a As Variant
        a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
            ' (1, 2, 3, 4, 5)

Можете да използвате метода Flatten заедно с други методи, като Append или Prepend, за да конкатенирате съвкупност от едномерни масиви в един едномерен масив.

### Пример:

Следва пример как методите Flatten и Append могат да се комбинират за конкатениране на три масива.

        'Създава три масива за този пример
        Dim a as Variant, b as Variant, c as Variant
        a = Array(1, 2, 3)
        b = Array(4, 5)
        c = Array(6, 7, 8, 9)
        'Конкатенира трите масива в един едномерен масив
        Dim arr as Variant
        arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
        '(1, 2, 3, 4, 5, 6, 7, 8, 9)

## ImportFromCSVFile

Импортира данните от файл със стойности, разделени със запетая (CSV). Запетаята може да бъде заменена с произволен друг знак.

Приложимият формат CSV е описан в документа IETF Common Format and MIME Type for CSV Files.

Всеки ред във файла съдържа по един пълен запис (не се разрешава разделяне на редове на части).
Последователности от рода на \n, \t, ... остават непроменени. За тяхната обработка използвайте метода SF_String.Unescape().

Методът връща двуизмерен масив, чиито редове съответстват на записите, прочетени от файла, а колоните – на полета от записите. Не се проверява дали типовете на полетата са съгласувани в рамките на колоните. Прави се опит за разпознаване на числа и дати.

Ако някой ред съдържа повече или по-малко полета от първия ред във файла, ще възникне изключение. Празните редове обаче просто се игнорират. Ако размерът на файла надхвърля ограничението за брой на елементите (вижте в кода), ще бъде издадено предупреждение и масивът ще бъде съкратен.

### Синтаксис:

svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]

### Параметри:

filename: името на текстовия файл, съдържащ данните. Името трябва да бъде изразено според текущото свойство FileNaming на услугата SF_FileSystem.

delimiter: единичен знак, обикновено запетая, точка и запетая или знак за табулация (подразбира се ",").

dateformat: когато dateformat е "YYYY-MM-DD", "DD-MM-YYYY" или "MM-DD-YYYY", датите се обработват по специален начин. Тирето (-) може да е заменено с точка (.), наклонена черта (/) или интервал. Другите формати на дати се игнорират. Датите с подразбирана стойност "" се смятат за обикновен текст.

### Пример:

Да вземем CSV файла myFile.csv със следното съдържание:

Име,РожденаДата,Адрес,Град

Ана,2002-03-31,"ул. „Хан Аспарух“ 81А",Варна

Филип,1998-05-04,"ул. „Тракия“ 125",Пловдив

Примерите на Basic и Python по-долу прочитат съдържанието на CSV файла в обект от типа Array.

##### В Basic

        Dim arr As Variant
        arr = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY-MM-DD")
        MsgBox arr(0, 3) ' Град
        MsgBox arr(1, 2) ' ул. „Хан Аспарух“ 81А
        MsgBox arr(1, 3) ' Варна

##### В Python

        from scriptforge import CreateScriptService
        svc = CreateScriptService("Array")
        bas = CreateScriptService("Basic")
        arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "YYYY-MM-DD")
        bas.MsgBox(arr[0][3]) # Град
        bas.MsgBox(arr[1][2]) # ул. „Хан Аспарух“ 81А
        bas.MsgBox(arr[1][3]) # Варна

## IndexOf

Претърсва едномерен масив за число, низ или дата. Сравняването на текст може да бъде или да не бъде чувствително към регистъра.
Ако масивът е сортиран, той трябва да е запълнен хомогенно, тоест всички елементи трябва да са скалари от един и същ тип (елементи със стойност Empty и Null са забранени).
Резултатът от метода е непредсказуем, когато масивът е обявен като сортиран, но в действителност не е такъв.
Ако масивът е сортиран, се извършва двоично търсене. В противен случай той просто се обхожда от началото до края и елементите Empty и Null се игнорират.
Ако търсенето е неуспешно, методът връща LBound(input array) - 1.

### Синтаксис:

svc.IndexOf(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int

### Параметри:

array_1d: масивът за обхождане.

tofind: търсено число, дата или низ.

casesensitive: само за сравняване на низове, подразбира се False.

sortorder: може да бъде "ASC" (възходящо сортиран), "DESC" (низходящо сортиран) или "" (несортиран). Подразбираната стойност е "".

### Пример:

        MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
        MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1

## Insert

Вмъква преди даден индекс на входния масив елементите, изброени като аргументи.
Аргументите се вмъкват без проверка. Всеки от тях може да бъде или скалар от произволен тип, или подмасив.

### Синтаксис:

svc.Insert(array_1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]

### Параметри:

array_1d: съществуващият масив, може да е празен.

before: индексът, преди който да се вмъква; трябва да е в интервала [LBound, UBound + 1].

arg0, arg1, ...: елементи, които ще бъдат вмъкнати в array_1d.

### Пример:

        Dim a As Variant
        a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
            ' (1, 2, "a", "b", 3)

## InsertSorted

Вмъква нов елемент на правилното място в сортиран масив.
Масивът трябва да е попълнен хомогенно, тоест всичките му елементи трябва да са скалари от един и същ тип.
Забранени са елементи Empty and Null.

### Синтаксис:

svc.InsertSorted(array_1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]

### Параметри:

array_1d: масивът, в който ще бъде вмъкната стойността.

item: скаларната стойност, която да бъде вмъкната, от същия тип като съществуващите елементи на масива.

sortorder: може да бъде "ASC" (възходящо сортиран) или "DESC" (низходящо сортиран).

casesensitive: само за сравняване на низове, подразбира се False.

### Пример:

        Dim a As Variant
        a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
            ' ("A", "B", "C", "a", "b")

## Intersection

Конструира множество във вид на индексиран от нула масив, като прилага операцията сечение върху двата входни масива. Резултатът включва елементите, които присъстват и в двата масива.
Резултатният масив е сортиран във възходящ ред.
Двата входни масива трябва да са попълнени хомогенно, с други думи, елементите им трябва да са скалари от един и същ тип. Елементи със стойност Empty и Null са забранени.
Сравняването на текст може да бъде чувствително или нечувствително към регистъра.

### Синтаксис:

svc.Intersection(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Параметри:

array1_1d: първият входен масив.

array2_1d: вторият входен масив.

casesensitive: отнася се само за масиви, попълнени с текстови елементи (подразбира се False).

### Пример:

        Dim a As Variant
        a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
            ' ("C", "b")

## Join2D

Обединява двумерен масив с два разделителя, един за колоните и един за редовете.

### Синтаксис:

svc.Join2D(array_2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str

### Параметри:

array_2d: всеки елемент трябва да е текст, число, дата или булева стойност.
Датите се преобразуват във формата YYYY-MM-DD hh:mm:ss.
Невалидните елементи се заместват с низ с нулева дължина.

columndelimiter: разделя колоните (подразбира се Tab/Chr(9)).

rowdelimiter: разделя редовете (подразбира се LineFeed/Chr(10)).

quote: ако е True, низовете се защитават с двойни кавички. Подразбира се False.

### Пример:

        ' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5           |
        '       | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
        Dim arr as Variant : arr = Array()
        arr = SF_Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
        arr = SF_Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
        Dim arrText as String
        arrText = SF_Array.Join2D(arr, ",", "/", False)
        ' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10

## Prepend

Добавя в началото на входния масив елементите, изброени като аргументи.

### Синтаксис:

svc.Prepend(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

### Параметри:

array_1d: съществуващият масив, може да е празен.

arg0, arg1, ...: списък от елементи, които да бъдат добавени в началото на array_1d.

### Пример:

        Dim a As Variant
        a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
            ' (4, 5, 1, 2, 3)

## PrependColumn

Добавя нова колона към лявата страна на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

### Синтаксис:

svc.PrependColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

### Параметри:

array_2d: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за последна колона на получения двумерен масив.

column: едномерен масив с толкова елементи, колкото са редовете в array_2d.

### Пример:

        Dim a As Variant, b As variant
        a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
            ' ((4, 1), (5, 2), (6, 3))
        b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i

## PrependRow

Добавя нов ред в началото на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

### Синтаксис:

svc.PrependRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]

### Параметри:

array_2d: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за последен ред на получения двумерен масив.

row: едномерен масив, съдържащ толкова елементи, колкото са колоните в array_2d.

### Пример:

        Dim a As Variant, b As variant
        a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
            ' ((4, 5, 6), (1, 2, 3))
        b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i

## RangeInit

Инициализира нов индексиран от нула масив с числови стойности.

### Синтаксис:

svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]

### Параметри:

from: стойност на първия елемент.

upto: последният елемент не трябва да надвишава UpTo.

bystep: разликата между първите два последователни елемента (подразбира се 1).

### Пример:

        Dim a As Variant
        a = SF_Array.RangeInit(10, 1, -1)
            ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)

## Reverse

Връща обърнатия едномерен входен масив.

### Синтаксис:

svc.Reverse(array_1d: any[0..*]): any[0..*]

### Параметри:

array_1d: масивът, който да бъде обърнат.

### Пример:

        Dim a As Variant
        a = SF_Array.Reverse(Array("a", 2, 3, 4))
            ' (4, 3, 2, "a")

## Shuffle

Връща случайна пермутация на едномерен масив.

### Синтаксис:

svc.Shuffle(array_1d: any[0..*]): any[0..*]

### Параметри:

array_1d: масивът, който да бъде разбъркан.

### Пример:

        Dim a As Variant
        a = SF_Array.Shuffle(Array(1, 2, 3, 4))
            ' Сега масивът a е в случаен ред, например (2, 3, 1, 4).

## Slice

Връща подмножество на едномерен масив.

### Синтаксис:

svc.Slice(array_1d: any[0..*], from: int, [upto: int]): any[0..*]

### Параметри:

array_1d: масивът, който да бъде разрязан.

from: долният индекс в array_1d на подмасива, който да бъде извлечен (включително from).

upto: горният индекс в array_1d на подмасива, който да бъде извлечен (включително upto). Подразбира се горната граница на array_1d. Ако upto < from, върнатият масив е празен.

### Пример:

        Dim a As Variant
        a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)

## Sort

Сортира едномерен масив във възходящ или низходящ ред. Сравняването на текст може да бъде чувствително или нечувствително към регистъра.
Масивът трябва да бъде запълнен хомогенно, тоест всички елементи трябва да бъдат скалари от един и същ тип.
Не се допускат елементи Empty и Null. По конвенция Empty < Null < всяка друга скаларна стойност.

### Синтаксис:

svc.Sort(array_1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]

### Параметри:

array_1d: масивът, който да бъде сортиран.

sortorder: може да бъде "ASC" (възходящо сортиран) или "DESC" (низходящо сортиран).

casesensitive: само за сравняване на низове, подразбира се False.

### Пример:

        Dim a As Variant
        a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
            ' ("A", "B", "C", "a", "b")

## SortColumns

Връща пермутация на колоните на двумерен масив, сортирани според стойностите на даден ред.
Редът трябва да бъде запълнен хомогенно, тоест всички елементи трябва да бъдат скалари от един и същ тип.
Не се допускат елементи Empty и Null. По конвенция Empty < Null < всяка друга скаларна стойност.

### Синтаксис:

svc.SortColumns(array_2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

### Параметри:

array_2d: двумерният масив, който да бъде сортиран.

rowindex: индексът на реда, по който ще се сортират колоните.

sortorder: може да бъде "ASC" (възходящо сортиран) или "DESC" (низходящо сортиран).

casesensitive: само за сравняване на низове, подразбира се False.

### Пример:

        ' arr = | 5, 7, 3 |
        '       | 1, 9, 5 |
        '       | 6, 1, 8 |
        Dim arr as Variant : arr = Array(5, 7, 3)
        arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
        arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
        arr = SF_Array.SortColumns(arr, 2, "ASC")
        ' arr = | 7, 5, 3 |
        '       | 9, 1, 5 |
        '       | 1, 6, 8 |

## SortRows

Връща пермутация на редовете на двумерен масив, сортирани според стойностите на дадена колона.
Колоната трябва да бъде запълнена хомогенно, тоест всички елементи трябва да бъдат скалари от един и същ тип.
Не се допускат елементи Empty и Null. По конвенция Empty < Null < всяка друга скаларна стойност.

### Синтаксис:

svc.SortRows(array_2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

### Параметри:

array_2d: масивът, който да бъде сортиран.

columnindex: индексът на колоната, по която ще се сортират редовете.

sortorder: може да бъде "ASC" (възходящо сортиран) или "DESC" (низходящо сортиран).

casesensitive: само за сравняване на низове, подразбира се False.

### Пример:

        ' arr = | 5, 7, 3 |
        '       | 1, 9, 5 |
        '       | 6, 1, 8 |
        Dim arr as Variant : arr = Array(5, 7, 3)
        arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
        arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
        arr = SF_Array.SortRows(arr, 0, "ASC")
        ' arr = | 1, 9, 5 |
        '       | 5, 7, 3 |
        '       | 6, 1, 8 |

## Transpose

Разменя редовете и колоните в двумерен масив.

### Синтаксис:

svc.Transpose(array_2d: any[0..*, 0..*]): any[0..*, 0..*]

### Параметри:

array_2d: двумерният масив, който да бъде транспониран.

### Пример:

        ' arr1 = | 1, 2 |
        '        | 3, 4 |
        '        | 5, 6 |
        arr1 = Array(1, 2)
        arr1 = SF_Array.AppendRow(arr1, Array(3, 4))
        arr1 = SF_Array.AppendRow(arr1, Array(5, 6))
        arr2 = SF_Array.Transpose(arr1)
        ' arr2 = | 1, 3, 5 |
        '        | 2, 4, 6 |
        MsgBox arr2(0, 2) ' 5

## TrimArray

Премахва от едномерен масив всички елементи Null, Empty и с нулева дължина.
Елементите низове се подрязват с функцията на LibreOffice Basic Trim().

### Синтаксис:

svc.TrimArray(array_1d: any[0..*]): any[0..*]

### Параметри:

array_1d: масивът, който да бъде подрязан.

### Пример:

        Dim a As Variant
        a = SF_Array.TrimArray(Array("A", "B", Null, " D "))
            ' ("A", "B", "D")

## Union

Конструира множество във вид на индексиран от нула масив, като прилага операцията обединение върху двата входни масива. Резултатът включва елементите, които присъстват в поне един от двата масива.
Резултатният масив е сортиран във възходящ ред.
Двата входни масива трябва да са попълнени хомогенно, с други думи, елементите им трябва да са скалари от един и същ тип. Елементи със стойност Empty и Null са забранени.
Сравняването на текст може да бъде чувствително или нечувствително към регистъра.

### Синтаксис:

svc.Union(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Параметри:

array1_1d: първият входен масив.

array2_1d: вторият входен масив.

casesensitive: приложим само ако масивите са попълнени с низове (подразбира се False).

### Пример:

        Dim a As Variant
        a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
            ' ("A", "B", "C", "Z", "b")

## Unique

Конструира множество от уникални стойности на базата на входния масив.
Входният масив трябва да е запълнен хомогенно, тоест елементите му трябва да са скалари от един и същ тип. Елементи Empty и Null са забранени.
Сравняването на текстове може да бъде чувствително или нечувствително към регистъра.

### Синтаксис:

svc.Unique(array_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Параметри:

array_1d: входният масив.

casesensitive: приложим само ако масивът е попълнен с низове (подразбира се False).

### Пример:

        Dim a As Variant
        a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
            '  ("A", "B", "C", "b")

В ScriptForge всички подпрограми или идентификатори на Basic с префикс „_“ са запазени за вътрешна употреба. Те не са предназначени за използване в макроси на Basic.

Теми, свързани с показаната

Функции за масиви

Използване на функции на Calc в макроси

ScriptForge.Dictionary service