Spis treści

# ŚREDNIA.JEŻELI function

Zwraca średnią arytmetyczną wszystkich komórek w zakresie spełniające dany warunek. Funkcja ŚREDNIA.JEŻELI sumuje wszystkie wyniki które pasują do logicznego test i dzieli tę sumę przez liczbę wybranych wartości.

Ta funkcja jest dostępna od wersji 4.0 LibreOffice.

### Składnia

ŚREDNIA.JEŻELI(Zakres; Kryterium [; Zakres_średniej ])

Zakres – argument wymagany. Macierz, nazwa nazwanego zakresu, etykieta kolumny lub wiersz zawierający liczby do uśrednienia, lub liczby, lub tekst dla warunku.

Kryterium: kryterium to odwołanie do pojedynczej komórki, liczba lub tekst. Używa się go do porównań zawartości komórek.

Odwołanie do pustej komórki jest interpretowane jako wartość liczbowa 0.

Pasującym wyrażeniem może być:

- Liczba lub wartość logiczna. Pasująca zawartość komórki jest równa liczbie lub wartości logicznej.

- Wartość rozpoczynająca się od komparatora (<, <=, =, >, >=, <>).

  W przypadku =, jeśli wartość jest pusta, dopasowuje puste komórki.

  W przypadku <>, jeśli wartość jest pusta, dopasowuje niepuste komórki.

  W przypadku <>, jeśli wartość nie jest pusta, dopasowuje dowolną zawartość komórki z wyjątkiem wartości, łącznie z pustymi komórkami.

  Uwaga: "=0" nie pasuje do pustych komórek.

  W przypadku = i <>, jeśli wartość nie jest pusta i nie może być interpretowana jako typ liczbowy lub jeden z jego podtypów oraz właściwość Kryteria wyszukiwania = i <> muszą się odnosić do całych komórek jest zaznaczona, porównanie dotyczy całej zawartości komórki, jeśli niezaznaczona, porównanie dotyczy dowolnej podczęści pola spełniającej kryteria. W przypadku = i <>, jeśli wartość nie jest pusta i nie może być interpretowana jako typ liczbowy lub jeden z jego podtypów.

- Inna wartość tekstowa. Jeśli właściwość Kryteria wyszukiwania = i <> muszą się odnosić do całych komórek jest prawdziwa, porównanie dotyczy całej zawartości komórki, jeśli fałszywe, porównanie dotyczy dowolnej podczęści pola spełniającej kryteria. Wyrażenie może zawierać tekst, liczby, wyrażenia regularne lub symbole wieloznaczne (jeśli włączono je w opcjach obliczeń).

Wyszukiwanie obsługuje symbole wieloznaczne lub wyrażenia regularne. Przy włączonych wyrażeniach regularnych możesz wpisać „all.*”, na przykład, aby znaleźć pierwszą lokalizację „all”, po której następuje dowolny znak. Jeśli chcesz wyszukać tekst, który jest również wyrażeniem regularnym, musisz poprzedzić każdy metaznak lub operator wyrażenia regularnego znakiem „\” albo umieścić tekst w \Q...\E. Możesz włączać i wyłączać automatyczną ocenę symboli wieloznacznych lub wyrażeń regularnych w LibreOffice - Preferencje Narzędzia - Opcje - LibreOffice Calc - Oblicz.

W przypadku korzystania z funkcji, w których jeden lub więcej argumentów to ciągi kryteriów wyszukiwania reprezentujące wyrażenie regularne, pierwszą próbą jest przekonwertowanie kryteriów ciągu na liczby. Na przykład „.0” zostanie przekonwertowane na 0,0 i tak dalej. Jeśli się powiedzie, dopasowanie nie będzie dopasowaniem wyrażenia regularnego, ale dopasowaniem liczbowym. Jednak po przełączeniu na ustawienia regionalne, w których separatorem dziesiętnym nie jest kropka, konwersja wyrażeń regularnych działa. Aby wymusić ocenę wyrażenia regularnego zamiast wyrażenia liczbowego, użyj wyrażenia, którego nie można błędnie odczytać jako liczbowego, takiego jak „.[0]”, „.\0” lub „(?i).0”.

Zakres_średniej – opcjonalne. Zakres wartości do obliczenia średniej.

Jeśli Zakres_uśrednienia nie jest określony, Zakres jest używany zarówno do obliczenia średniej, jak i do wyszukiwania według warunku. Jeśli określono Zakres uśrednienia, Zakres będzie używany tylko do testu warunku, natomiast Zakres uśrednienia będzie używany do obliczeń średniej.

Jeśli komórka w zakresie wartości do obliczenia średniej jest pusta lub zawiera tekst, funkcja ŚREDNIA.JEŻELI zignoruje tę komórkę.
Jeśli cały zakres jest pusty, zawiera tylko tekst lub wszystkie wartości zakresu nie spełniają warunku (lub dowolna ich kombinacja), funkcja zwraca błąd #DZIEL/0!

### Przykłady

Poniżej opisano działanie tego pola na tabeli

| A | B | C
1 | Nazwa produktu | Sales | Revenue
2 | ołówek | 20 | 65
3 | ołów | 35 | 85
4 | fotoalbum | 20 | 190
5 | album | 17 | 180
6 | ołóweczek | nie | nie

We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.

#### Proste użycie

=ŚREDNIA.JEŻELI(B2:B6;"<35")

Oblicza średnią wartości z zakresu B2:B6, która jest mniejsza niż 35. Zwraca 19, ponieważ drugi wiersz nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;"<"&MAKS(B2:B6))

Oblicza średnią wartości z tego samego zakresu, która jest mniejsza niż maksymalna wartość tego zakresu. Zwraca 19, ponieważ największa wartość (drugi wiersz) nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;">"&MIN.K(B2:B6;1))

Oblicza średnią wartości z tego samego zakresu, która jest większa niż pierwsza, najmniejsza wartość tego zakresu. Zwraca 25, ponieważ pierwsza, najmniejsza wartość (czwarty wiersz) nie bierze udziału w obliczeniach.

#### Użycie Zakres_średniej

=ŚREDNIA.JEŻELI(B2:B6;"<35";C2:C6)

Funkcja przeszukuje jakie wartości są mniej niż 35 w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Zwraca 145, ponieważ drugi wiersz nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;">"&MIN(B2:B6);C2:C6)

Funkcja przeszukuje jakie wartości z zakresu B2:B6 są większe niż ostatnie wartości w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z C2:C6. Zwraca 113,31 ponieważ czwarty wiersz (w którym znajduje się co najmniej wartość w zakresie B2: B6) nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;"<"&MAKS.K(B2:B6;2);C2:C6)

Funkcja przeszukuje jakie wartości z zakresu B2:B6 są mniejsze niż druga, duża wartość w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Zwraca 180, ponieważ tylko czwarty wiersz bierze udział w obliczeniach.

#### Użycie wyrażeń regularnych

=ŚREDNIA.JEŻELI(A2:A6;"ołów";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają tylko słowo "ołów" i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Zwraca 35, ponieważ tylko drugi wiersz bierze udział w obliczeniach. Wyszukiwanie wykonane jest w zakresie A2:A6, lecz wartości są zwracane z zakresu B2:B6.

=ŚREDNIA.JEŻELI(A2:A6;"ołów.*";B2:B6)

Funkcja wyszukuje, które komórki z zakresu A2:A6 zaczynają się od słowa "ołów", a na końcu zawierają dowolną liczbę innych symboli i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Zwraca 27,5, ponieważ teraz także słowo "ołówek" spełnia warunek i oba, pierwszy oraz drugi wiersz, biorą udział w obliczeniach.

=ŚREDNIA.JEŻELI(A2:A6;".*album.*";B2:B6)

Funkcja wyszukuje, które komórki z zakresu A2:A6 zawierają słowo "książka", a na początku i na końcu zawierają dowolną liczbę innych symboli i oblicza średnią odpowiadającą wartościom z zakresu B2: B6. Zwraca 18,5, ponieważ tylko trzeci i czwarty wiersz bierze udział w obliczeniach.

#### Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji ŚREDNIA.JEŻELI.

=ŚREDNIA.JEŻELI(A2:A6;".*"&E2&".*";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają kombinację znaków określonych w komórce E2, a na początku i na końcu zawierają dowolną ilością innych znaków i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Jeśli komórka E2 = książka, funkcja zwraca 18,5.

=ŚREDNIA.JEŻELI(B2:B6;"<"&E2;C2:C6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 są mniejsze niż wartość określona w E2 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Jeśli komórka E2 = 35, funkcja zwraca 145.

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)

Tematy pokrewne

Strona wiki ŚREDNIA.JEŻELI.

ŚREDNIA, ŚREDNIA.A, ODCH.ŚREDNIE

LICZ.WARUNKI, MIN.WARUNKÓW, MAKS.WARUNKÓW, ŚREDNIA.JEŻELI, SUMA.WARUNKÓW

Lista wyrażeń regularnych