Spis treści

# Funkcje finansowe - część pierwsza

Ta kategoria zawiera matematyczne funkcje finansowe programu LibreOffice Calc.

## AMORT.LIN

Oblicza wartość amortyzacji dla okresu rozliczeniowego w amortyzacji liniowej. Jeśli środek trwały został zakupiony w trakcie okresu rozliczeniowego, uwzględniana jest proporcjonalna wartość amortyzacji.

#### Składnia

AMORT.LIN(cena; data_nabycia; pierwszy_okres; odzysk; okres; stopa [; podstawa])

Cena to cena nabycia środka trwałego.

Data_nabycia oznacza datę nabycia środka trwałego.

Pierwszy_okres stanowi końcową datę pierwszego okresu rozliczeniowego.

Odzysk to wartość odzysku środka trwałego na koniec okresu amortyzacji.

Okres oznacza rozważany okres rozliczeniowy.

Stopa stanowi stopę amortyzacji.

Podstawa (parametr opcjonalny): wybrana z listy opcji; oznacza sposób obliczania lat.

Podstawa | Obliczenia
--- | ---
0 lub brak | Metoda amerykańska (NASD), 12 miesięcy po 30 dni
1 | Dokładna liczba dni w miesiącu, dokładna liczba dni w roku
2 | Dokładna liczba dni w miesiącu, rok ma 360 dni
3 | Dokładna liczba dni w miesiącu, rok ma 365 dni
4 | Metoda europejska, 12 miesięcy po 30 dni

#### Przykład

Aktywo zostało nabyte w dniu 2020-02-01 kosztem 2000 jednostek waluty. Data zakończenia pierwszego okresu rozliczeniowego to 2020-12-31. Wartość odzysku środka trwałego na koniec jego okresu użytkowania podlegającego amortyzacji wyniesie 10 jednostek walutowych. Stawka amortyzacji wynosi 0,1 (10%), a rok liczony jest metodą amerykańską (Podstawa 0). Zakładając amortyzację liniową, jaka jest kwota amortyzacji w czwartym okresie amortyzacji?

=AMORT.LIN(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) zwraca kwotę amortyzacji 200 jednostek walutowych.

Należy pamiętać, że Podstawa 2 nie jest obsługiwana przez program Microsoft Excel. Dlatego jeśli użyjesz Podstawy 2 i wyeksportujesz dokument do formatu XLSX, po otwarciu w Excelu zwróci on błąd.

## AMORT.NIELIN

Oblicza wartość amortyzacji dla okresu rozliczeniowego w amortyzacji degresywnej. W odróżnieniu od funkcji AMORT.LIN, tutaj zastosowano współczynnik amortyzacji niezależny od czasu użytkowania.

#### Składnia

AMORT.NIELIN(cena; data_nabycia; pierwszy_okres; odzysk; okres; stopa; [; podstawa])

Cena to cena nabycia środka trwałego.

Data_nabycia oznacza datę nabycia środka trwałego.

Pierwszy_okres stanowi końcową datę pierwszego okresu rozliczeniowego.

Odzysk to wartość odzysku środka trwałego na koniec okresu amortyzacji.

Okres oznacza rozważany okres rozliczeniowy.

Stopa stanowi stopę amortyzacji.

Podstawa (parametr opcjonalny): wybrana z listy opcji; oznacza sposób obliczania lat.

Podstawa | Obliczenia
--- | ---
0 lub brak | Metoda amerykańska (NASD), 12 miesięcy po 30 dni
1 | Dokładna liczba dni w miesiącu, dokładna liczba dni w roku
2 | Dokładna liczba dni w miesiącu, rok ma 360 dni
3 | Dokładna liczba dni w miesiącu, rok ma 365 dni
4 | Metoda europejska, 12 miesięcy po 30 dni

#### Przykład

Aktywo zostało nabyte w dniu 2020-02-01 kosztem 2000 jednostek waluty. Data zakończenia pierwszego okresu rozliczeniowego to 2020-12-31. Wartość odzysku środka trwałego na koniec jego okresu użytkowania podlegającego amortyzacji wyniesie 10 jednostek walutowych. Stawka amortyzacji wynosi 0,1 (10%), a rok liczony jest metodą amerykańską (Podstawa 0). Zakładając degresywną amortyzację, jaka jest kwota amortyzacji w czwartym okresie amortyzacji?

=AMORT.NIELIN(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) zwraca kwotę amortyzacji równą 163 jednostkom waluty.

Należy pamiętać, że Podstawa 2 nie jest obsługiwana przez program Microsoft Excel. Dlatego jeśli użyjesz Podstawy 2 i wyeksportujesz dokument do formatu XLSX, po otwarciu w Excelu zwróci on błąd.

## DB

Zwraca amortyzację środka trwałego za podany okres metodą równomiernego spadku wartości.

Ta forma amortyzacji jest używana w celu uzyskania wyższej wartości amortyzacji na początku użytkowania (w odróżnieniu do amortyzacji liniowej) Wartość amortyzacji jest zmniejszana po każdym okresie amortyzacji przez amortyzację uwzględnioną już w cenie początkowej.

#### Składnia

DB(koszt; odzysk; czas_użytkowania; okres [; miesiąc])

Cena stanowi koszt początkowy środka trwałego.

Odzysk stanowi wartość środka trwałego na koniec amortyzacji.

Czas_użytkowania oznacza okres obejmujący całkowity czas amortyzacji środka trwałego.

Okres określa długość każdego okresu. Długość okresu należy wprowadzić w takiej samej jednostce czasu, co okres amortyzacji.

Miesiąc (parametr opcjonalny) to liczba miesięcy w pierwszym roku amortyzacji. Przy braku parametru przyjmuje się liczbę 12.

#### Przykład

System komputerowy o początkowym koszcie 25 000 jednostek waluty ma być amortyzowany przez okres trzech lat. Wartość ratunkowa ma wynieść 1000 jednostek walutowych. Pierwszy okres amortyzacji obejmuje 6 miesięcy. Jaka jest stała amortyzacja salda degresywnego systemu komputerowego w drugim okresie, czyli pełnym roku liczonym od końca pierwszego półrocza?

=DB(25000; 1000; 3; 2; 6) zwraca 11 037,95 jednostek walutowych.

## DDB

Zwraca amortyzację środka trwałego za podany okres metodą arytmetycznego spadku wartości.

Z tej formy amortyzacji, w odróżnieniu do amortyzacji liniowej, korzysta się w sytuacjach, kiedy jest wymagana wysoka początkowa wartość amortyzacji. Wartość amortyzacji maleje wraz z każdym okresem. Ta forma używana jest zwykle w przypadku środków trwałych o wyższym spadku wartości krótko po zakupie (np. samochodów lub komputerów). Należy pamiętać, że w tym rodzaju obliczeń wartość księgowa nigdy nie spada do zera.

#### Składnia

DDB(koszt; odzysk; czas_użytkowania; okres [; współczynnik])

Cena stanowi cenę zakupu środka trwałego.

Odzysk określa wartość środka trwałego na koniec okresu użytkowania.

Czas_użytkowania to liczba okresów (np. lat lub miesięcy) oznaczająca, ile czasu środek ma być używany.

Okres oznacza okres, dla którego ma być obliczona wartość.

Współczynnik (parametr opcjonalny) to współczynnik zmniejszania amortyzacji. Jeśli nie wprowadzono współczynnika, domyślnie przyjmowana jest wartość 2.

#### Przykład

System komputerowy o początkowej cenie 75 000 jednostek walutowych ma być amortyzowany miesięcznie przez 5 lat. Wartość na koniec amortyzacji ma wynosić 1 jednostkę walutową. Współczynnik = 2.

=DDB(75000;1;60;12;2) = 1721,81 jednostek walutowych. Amortyzacja obliczana metodą podwójnego spadku przez dwanaście miesięcy od zakupu wynosi więc 1721,81 jednostek walutowych.

## EFEKTYWNA

Zwraca efektywną roczną stopę procentową przy danej rocznej stopie nominalnej.

Nominalne stopy procentowe odnoszą się do wysokości odsetek planowaną na koniec okresu rozliczeniowego. Odsetki efektywne rosną wraz z kolejnymi dokonanymi płatnościami. Odsetki są zatem często płacone w ratach (np. miesięcznie lub kwartalnie) przed końcem okresu rozliczeniowego.

#### Składnia

EFEKTYWNA(nom; P)

Nom to odsetki nominalne.

P oznacza liczbę okresów płatności odsetek w roku.

#### Przykład

Ile wynosi rzeczywista stopa odsetkowa (stopa efektywna), jeśli nominalna roczna stopa odsetkowa wynosi 9,75% i zdefiniowano cztery okresy rozliczeniowe odsetek?

=EFEKTYWNA(9,75%;4) = 10,11%. Efektywna roczna stopa procentowa wynosi zatem 10,11%.

## EFEKTYWNA.DODATKOWE

Oblicza efektywne roczne stopy oprocentowania na podstawie nominalnej stopy oprocentowania i liczby płatności odsetek w ciągu roku.

Funkcje, których nazwy kończą się na _DODATKOWE lub _EXCEL2003, zwracają te same wartości, co odpowiadające im funkcje programu Microsoft Excel. Aby uzyskać wyniki oparte na standardach międzynarodowych, należy użyć funkcji o nazwie bez przyrostka.

#### Składnia

EFEKTYWNA.DODATKOWE(stopa_nominalna; okresy_w_roku)

Stopa_nominalna to roczna nominalna stopa oprocentowania.

Okresy_w_roku oznaczają liczbę płatności odsetek w ciągu roku.

#### Przykład

Ile wynosi efektywna roczna stopa procentowa dla nominalnej stopy procentowej na poziomie 5,25% przy założeniu płatności kwartalnych?

=EFEKTYWNA.DODATKOWE(0,0525;4) zwraca wartość 0,053543 lub 5,3543%.

## IRR

Oblicza wewnętrzną stopę zwrotu z inwestycji. Wartości oznaczają przepływ środków pieniężnych obliczany w regularnych odstępach czasu. Co najmniej jedna wartość musi być ujemna (płatności) i co najmniej jedna wartość musi być dodatnia (dochód).

Jeśli płatność jest wykonywana w nieregularnych odstępach czasu, użyj funkcji XIRR.

#### Składnia

IRR(wartości [; wartość_oczekiwana])

Wartości to macierz zawierająca wartości.

Wartość_oczekiwana (parametr opcjonalny) oznacza wartość szacowaną. Do obliczeń wewnętrznej stopy zwrotu korzysta się z metody iteracyjnej. W przypadku podania niewielu wartości iteracja jest możliwa po wskazaniu wstępnej wartości oczekiwanej.

Ta funkcja ignoruje dowolny tekst lub puste komórki w zakresie danych. Jeśli podejrzewasz, że ta funkcja daje błędne wyniki, poszukaj tekstu w zakresach danych. Aby wyróżnić zawartość tekstową w zakresie danych, użyj funkcji wyróżniania wartości.

#### Przykład

Przy założeniu, że zawartość komórek wynosi: A1=-10000, A2=3500, A3=7600 i A4=1000, formuła =IRR(A1:A4) daje wynik 11,33%.

Ze względu na zastosowaną metodę iteracyjną IRR może zawieść i zwrócić Błąd 523, z błędem 'Błąd: obliczenie nie konwerguje' na pasku stanu. W takim przypadku wypróbuj inną wartość dla Zgadnij.

## ISPMT

Oblicza wysokość odsetek w przypadku stałych rat amortyzacyjnych.

#### Składnia

ISPMT(stopa; okres; łączna_liczba_okresów; inwestycja)

Stopa to okresowa stopa procentowa.

Okres oznacza liczbę rat do obliczenia odsetek.

Łączna_liczba_okresów stanowi całkowitą liczbę okresów.

Inwestycja określa wartość inwestycji.

#### Przykład

Dla dwuletniego kredytu o wartości 120 000 jednostek walutowych i miesięcznych płatności przy rocznej stopie odsetek wynoszącej 12% należy obliczyć wysokość odsetek po 1,5 roku.

=ISPMT(1%;18;24;120000) = -300 jednostek walutowych. Wysokość miesięcznych odsetek po 1,5 roku wynosi 300 jednostek walutowych.

## KWOTA.WYKUP

Oblicza kwotę wypłacaną w danym momencie dla papierów wartościowych o oprocentowaniu stałym.

#### Składnia

KWOTA.WYKUP(rozliczenie; data_spłaty; inwestycja; dyskonto [; podstawa])

Rozliczenie to data nabycia papieru wartościowego.

Data_spłaty oznacza datę płatności (ważności) papieru wartościowego.

Inwestycja określa sumę zakupu.

Dyskonto stanowi dyskonto procentowe nabycia papieru wartościowego.

Podstawa (parametr opcjonalny): wybrana z listy opcji; oznacza sposób obliczania lat.

Podstawa | Obliczenia
--- | ---
0 lub brak | Metoda amerykańska (NASD), 12 miesięcy po 30 dni
1 | Dokładna liczba dni w miesiącu, dokładna liczba dni w roku
2 | Dokładna liczba dni w miesiącu, rok ma 360 dni
3 | Dokładna liczba dni w miesiącu, rok ma 365 dni
4 | Metoda europejska, 12 miesięcy po 30 dni

#### Przykład

Data rozliczenia: 15 lutego 1999, data spłaty: 15 maja 1999, suma inwestycji: 1000 jednostek walutowych, dyskonto: 5,75 %, podstawa: saldo dzienne/360 = 2.

Kwota wypłacana w dniu spłaty obliczana jest w następujący sposób:

=KWOTA.WYKUP("1999-02-15";"1999-05-15";1000;0,0575;2) zwraca wartość 1014,420266.

## NAL.ODS

Oblicza należne odsetki od papierów wartościowych w przypadku rat okresowych.

#### Składnia

NAL.ODS(emisja; pierwsze_odsetki; rozliczenie; stopa; cena_nominalna; częstotliwość [; podstawa])

Emisja (wymagana) stanowi datę emisji papieru wartościowego.

Pierwsze_odsetki (wymagane) określają datę pierwszej raty odsetek od papieru wartościowego.

Rozliczenie (wymagane) to data, dla której mają zostać obliczone narosłe do tej chwili należne odsetki.

Stopa (wymagana) oznacza roczną nominalną stopę procentową (stopa procentowa kuponu)

Cena_nominalna (parametr opcjonalny) to wartość nominalna zabezpieczenia. W przypadku pominięcia używana jest wartość domyślna 1000.

Zalecamy, aby zawsze określać wymaganą wartość dla argumentu Cena_nominalna NAL.ODS, zamiast zezwalać Calc na zastosowanie dowolnej wartości domyślnej. Dzięki temu formuła będzie łatwiejsza do zrozumienia i łatwiejsza w utrzymaniu.

Częstotliwość (wymagana) stanowi liczbę płatności odsetek w roku (1, 2 lub 4).

Podstawa (parametr opcjonalny): wybrana z listy opcji; oznacza sposób obliczania lat.

Podstawa | Obliczenia
--- | ---
0 lub brak | Metoda amerykańska (NASD), 12 miesięcy po 30 dni
1 | Dokładna liczba dni w miesiącu, dokładna liczba dni w roku
2 | Dokładna liczba dni w miesiącu, rok ma 360 dni
3 | Dokładna liczba dni w miesiącu, rok ma 365 dni
4 | Metoda europejska, 12 miesięcy po 30 dni

#### Przykład

Papier wartościowy został wyemitowany 2001-02-28. Spłatę pierwszych odsetek zaplanowano na 2001-08-31. Data rozliczenia to 2001-05-01. Stopa oprocentowania wynosi 0,1 (10%), a cena nominalna wynosi 1000 jednostek walutowych. Odsetki są wypłacane co pół roku (częstotliwość wynosi 2). Jako podstawę przyjmuje się metodę amerykańską (0). Jakie do tej pory narosły odsetki?

=NAL.ODS("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;2;0) zwraca wartość 16,94444.

## NAL.ODS.WYKUP

Oblicza należne odsetki od papierów wartościowych w przypadku płatności jednorazowej w dniu rozliczenia.

#### Składnia

NAL.ODS.WYKUP(emisja; rozliczenie; stopa [; cena_nominalna; [; podstawa]])

Emisja (wymagana) stanowi datę emisji papieru wartościowego.

Rozliczenie (wymagane) to data, dla której mają zostać obliczone narosłe do tej chwili należne odsetki.

Stopa (wymagana) oznacza roczną nominalną stopę procentową (stopa procentowa kuponu).

Cena_nominalna (parametr opcjonalny) to wartość nominalna zabezpieczenia. W przypadku pominięcia używana jest wartość domyślna 1000.

Zalecamy, aby zawsze określać wymaganą wartość dla argumentu Cena_nominalna NAL.ODS.WYKUP, zamiast zezwalać Calc na zastosowanie dowolnej wartości domyślnej. Dzięki temu formuła będzie łatwiejsza do zrozumienia i łatwiejsza w utrzymaniu.

Podstawa (parametr opcjonalny): wybrana z listy opcji; oznacza sposób obliczania lat.

Podstawa | Obliczenia
--- | ---
0 lub brak | Metoda amerykańska (NASD), 12 miesięcy po 30 dni
1 | Dokładna liczba dni w miesiącu, dokładna liczba dni w roku
2 | Dokładna liczba dni w miesiącu, rok ma 360 dni
3 | Dokładna liczba dni w miesiącu, rok ma 365 dni
4 | Metoda europejska, 12 miesięcy po 30 dni

#### Przykład

Papier wartościowy został wyemitowany 2001-04-01. Spłatę pierwszych odsetek zaplanowano na 2001-06-15. Stopa oprocentowania wynosi 0,1 (10%), a cena nominalna wynosi 1000 jednostek walutowych. Jako podstawę rozliczenia dziennego/rocznego przyjmuje się saldo dzienne (3). Jakie do tej pory narosły odsetki?

=NAL.ODS.WYKUP("2001-04-01";"2001-06-15";0.1;1000;3) zwraca wartość 20,54795.

## PV

Zwraca wartość bieżącą inwestycji wynikającą z serii regularnych płatności.

Służy do obliczenia kwoty, którą należy zainwestować danego dnia przy stałej stopie procentowej, aby uzyskać określoną kwotę raty rocznej w ciągu określonej liczby okresów. Umożliwia także określenie, ile pieniędzy ma pozostać po upłynięciu okresu inwestycji oraz czy kwota będzie wypłacana na początku, czy na końcu każdego okresu.

Powyższe wartości wprowadza się w postaci liczb, wyrażeń lub odwołań. Na przykład jeśli odsetki są wypłacane rocznie na poziomie 8%, ale okresem rozliczeniowym ma być miesiąc, jako parametr stopa należy wprowadzić wartość 8%/12, a LibreOffice Calc automatycznie obliczy prawidłowy współczynnik.

#### Składnia

PV(stopa; NPER; PMT [; FV [; typ]])

Stopa definiuje stopę procentową dla pojedynczego okresu.

NPer oznacza całkowitą liczbę okresów (płatności).

Spłata jest płatnością dokonywaną na każdy okres.

Wartość_przyszła (parametr opcjonalny) definiuje przyszłą wartość pozostałą po zapłaceniu ostatniej raty.

Typ (parametr opcjonalny) oznacza datę realizacji płatności. Typ = 1 oznacza realizację płatności na początku okresu, natomiast 0 – na końcu.

W funkcjach programu LibreOffice Calc parametry oznaczone jako „opcjonalne” można pominąć tylko wtedy, gdy żaden parametr nie występuje. Na przykład w funkcji z czterema parametrami, gdzie ostatnie dwa parametry są oznaczone jako „opcjonalne”, możesz pominąć parametr 4 lub parametry 3 i 4, ale nie możesz pominąć samego parametru 3.

#### Przykład

Ile wynosi bieżąca wartość inwestycji, jeśli miesięcznie należy płacić 500 jednostek walutowych, a roczna stopa procentowa wynosi 8%? Okres płatności wynosi 48 miesięcy, a po jego zakończeniu powinno pozostać 20 000 jednostek walutowych.

=PV(8%/12;48;500;20000) = -35 019,37 jednostek walutowych. Aby przy tak określonych warunkach przez 48 miesięcy otrzymywać 500 jednostek, a po zakończeniu tego okresu pozostało 20 000 jednostek walutowych, w danej chwili należy zdeponować 35 019,37 jednostek walutowych. Sprawdzenie: 48 x 500 jednostek walutowych + 20 000 jednostek walutowych = 44 000 jednostek walutowych. Różnicę pomiędzy tą kwotą i zdeponowaną sumą stanowią wypłacone odsetki.

Wprowadzenie do formuły odwołań zamiast wartości pozwala obliczyć dowolną liczbę scenariuszy hipotetycznych. Należy pamiętać, że odwołania do stałych muszą być zdefiniowane jako odwołania bezwzględne. Przykłady tego typu zastosowań można znaleźć przy funkcjach dotyczących amortyzacji.

## ROCZ.PRZYCH

Oblicza okres odsetkowy w latach dla papierów wartościowych o oprocentowaniu stałym.

#### Składnia

ROCZ.PRZYCH(rozliczenie; data_spłaty; kupon; rentowność; częstotliwość [; podstawa])

Rozliczenie to data nabycia papieru wartościowego.

Data_spłaty oznacza datę płatności (ważności) papieru wartościowego.

Kupon stanowi roczną stopę procentową kuponu (nominalna stopa procentowa kuponu)

Rentowność określa roczną rentowność papieru wartościowego.

Częstotliwość stanowi liczbę płatności odsetek w roku (1, 2 lub 4).

Podstawa (parametr opcjonalny): wybrana z listy opcji; oznacza sposób obliczania lat.

Podstawa | Obliczenia
--- | ---
0 lub brak | Metoda amerykańska (NASD), 12 miesięcy po 30 dni
1 | Dokładna liczba dni w miesiącu, dokładna liczba dni w roku
2 | Dokładna liczba dni w miesiącu, rok ma 360 dni
3 | Dokładna liczba dni w miesiącu, rok ma 365 dni
4 | Metoda europejska, 12 miesięcy po 30 dni

#### Przykład

Papier wartościowy został wyemitowany 2001-01-01. Dzień spłaty to 2006-01-01. Stopa procentowa kuponu wynosi 8%. Rentowność wynosi 9,0%. Odsetki są wypłacane co pół roku (częstotliwość wynosi 2). Ile trwa zmodyfikowany okres odsetkowy przy założeniu salda dziennego (podstawa wynosi 3)?

=ROCZ.PRZYCH("2001-01-01";"2006-01-01";0,08;0,09;2;3) zwraca 4,2 roku.

## STOPA.DYSK

Oblicza procentową obniżkę (dyskonto) papierów wartościowych.

#### Składnia

STOPA.DYSK(rozliczenie; data_spłaty; cena; wykup [; podstawa])

Rozliczenie to data nabycia papieru wartościowego.

Data_spłaty oznacza datę płatności (ważności) papieru wartościowego.

Cena to cena za każde 100 jednostek walutowych wartości nominalnej papieru wartościowego.

Wykup stanowi wartość wykupu każdych 100 jednostek walutowych wartości nominalnej papieru wartościowego.

Podstawa (parametr opcjonalny): wybrana z listy opcji; oznacza sposób obliczania lat.

Podstawa | Obliczenia
--- | ---
0 lub brak | Metoda amerykańska (NASD), 12 miesięcy po 30 dni
1 | Dokładna liczba dni w miesiącu, dokładna liczba dni w roku
2 | Dokładna liczba dni w miesiącu, rok ma 360 dni
3 | Dokładna liczba dni w miesiącu, rok ma 365 dni
4 | Metoda europejska, 12 miesięcy po 30 dni

#### Przykład

Papiery wartościowe zakupiono 2001-01-25, datę spłaty ustalono na 2001-11-15. Cena zakupu wynosi 97, wartość wykupu wynosi 100. Ile wynosi rozliczenie (dyskonto) przy założeniu salda dziennego (podstawa = 3)?

=STOPA.DYSK("2001-01-25";"2001-11-15";97;100;3) zwraca wartość 0,0372 czyli 3,72 procenta.

## SYD

Zwraca stopę amortyzacji z arytmetycznym spadkiem wartości.

Służy do obliczania kwoty amortyzacji dla jednego okresu całkowitego czasu amortyzacji artykułu. Amortyzacja z arytmetycznym spadkiem wartości powoduje zmniejszenie o stałą wartość kwoty amortyzacji dla kolejnych okresów.

#### Składnia

SYD (koszt;odzysk;czas_użytkowania;okres)

Cena stanowi koszt początkowy środka trwałego.

Odzysk to wartość środka trwałego po amortyzacji.

Czas_użytkowania oznacza okres obejmujący całkowity czas amortyzacji środka trwałego.

Okres definiuje okres obliczeniowy amortyzacji.

#### Przykład

System wideo o początkowej cenie 50 000 jednostek walutowych ma być amortyzowany rocznie przez kolejne 5 lat. Wartość odzysku wynosi 10 000 jednostek walutowych. Należy obliczyć amortyzację dla pierwszego roku.

=SYD(50000;10000;5;1)=13 333,33 jednostek walutowych. Kwota amortyzacji za pierwszy rok użytkowania wynosi 13 333,33 jednostek walutowych.

Aby uzyskać przegląd stóp amortyzacji za dany okres, najlepiej zdefiniować tabelę amortyzacji. Wprowadzając obok siebie różne formuły amortyzacji dostępne w programie LibreOffice Calc, można ocenić, która forma amortyzacji jest najbardziej właściwa. Wprowadź następujące dane do tabeli:

| A | B | C | D | E
1 | Cena zakupu | Wartość odzysku | Czas użytkowania | Okres | Amortyzacja SYD
2 | 50 000 jednostek walutowych | 10 000 jednostek walutowych | 5 | 1 | 13 333,33 jednostek walutowych
3 |  |  |  | 2 | 10 666,67 jednostek walutowych
4 |  |  |  | 3 | 8 000,00 jednostek walutowych
5 |  |  |  | 4 | 5 333,33 jednostek walutowych
6 |  |  |  | 5 | 2 666,67 jednostek walutowych
7 |  |  |  | 6 | 0,00 jednostek walutowych
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Suma | 40 000,00 jednostek walutowych

Formuła w komórce E2 wygląda następująco:

=SYD($A$2;$B$2;$C$2;D2)

Formuła została skopiowana w kolumnie E aż do komórki E11 (zaznacz komórkę E2, a następnie przeciągnij myszą w dół prawy dolny narożnik komórki).

Komórka E13 zawiera formułę używaną do sprawdzenia całkowitych kwot amortyzacji. Formuła korzysta z funkcji SUMA.JEŻELI, ponieważ nie można uwzględniać ujemnych wartości w komórkach E8:E11. Komórka A13 zawiera warunek >0. Formuła w komórce E13 wygląda następująco:

=SUMA.JEŻELI(E2:E11;A13)

Tabela pozwala obliczyć amortyzację w okresie 10-letnim lub przy wartości odzysku na poziomie 1 jednostki walutowej, pozwala też wprowadzić inną cenę zakupu.

Funkcje finansowe część druga

Funkcje finansowe część trzecia

Funkcje według kategorii