Contenido

# Función CreateUnoServiceWithArguments

Instantiates a UNO service with the ProcessServiceManager, including supplemental optional arguments.

### Sintaxis:

        CreateUnoServiceWithArguments(ServiceName As String, Arguments() As Variant) As Object

UNO services that can be used with CreateUnoServiceWithArguments function are identifiable with method names that follow a createInstanceWith.. or createWith.. naming pattern.

### Devuelve tipo:

Objeto

For a list of available services, visit the com::sun::star Module reference page.

### Parámetros:

Nombre | Tipo | Descripción
--- | --- | ---
ServiceName | String | The UNO service name to be created.
Argumentos | Variant | One to many arguments that specify the instance of the service. Arguments are stored as a one dimensional array, according to their positions in the constructor method definition.

### Ejemplo:

The com.sun.star.ui.dialogs.FilePicker example below displays a built-in LibreOffice Save As dialog with two extra controls: a listbox and a checkbox.

        Sub FileSaveAsDialog()
           td = com.sun.star.ui.dialogs.TemplateDescription
           options = td.FILESAVE_AUTOEXTENSION_TEMPLATE
           dlg = CreateUnoServiceWithArguments( _
              "com.sun.star.ui.dialogs.FilePicker", _
              Array(options))
           dlg.execute()
        End Sub ' FileSaveAsDialog

Los diálogos de archivos —como Abrir, Guardar como, Insertar texto y similares— están disponibles de dos formas diferentes:

- Como diálogos de selección de archivos nativos del administrador de ventanas de su sistema operativo.

- Como diálogo de selección de archivos integrados de LibreOffice.

Utilice LibreOffice - Preferencias Herramientas - Opciones - LibreOffice - General para pasar de uno a otro.

UNO services have an extensive online documentation in the api.libreoffice.org website. Visit the FilePicker Service reference page to learn more about the methods provided by the service used in the example above.

### Ejemplo:

The following code uses the service com.sun.star.security.DocumentDigitalSignatures to sign the current document:

    Sub  SignCurrentDocDialog
       Dim pv(0) as new com.sun.star.beans.PropertyValue
       pv(0).Name  = "StorageFormat"
       pv(0).Value = "ZipFormat"
       mode = com.sun.star.embed.ElementModes
       sf = CreateUnoService("com.sun.star.embed.StorageFactory")
       storage = sf.createInstanceWithArguments(Array(ThisComponent.URL, mode.WRITE, pv))
       dds = CreateUnoServiceWithArguments( _
          "com.sun.star.security.DocumentDigitalSignatures", _
          Array("1.2", True))
       dds.signDocumentContent(storage, Null)
    End Sub ' SignCurrentDocDialog

CreateWithVersion and createWithVersionAndValidSignature constructor methods in com.sun.star.security.DocumentDigitalSignatures UNO service indicate two different ways of instantiating this service with CreateUnoServiceWithArguments function.

Temas relacionados

Función CreateUnoService

Objetos, funciones y servicios de UNO

Using Calc Functions in Macros

¡Necesitamos su ayuda!